Chinaunix首页 | 论坛 | 博客
  • 博客访问: 1955063
  • 博文数量: 298
  • 博客积分: 7876
  • 博客等级: 准将
  • 技术积分: 5500
  • 用 户 组: 普通用户
  • 注册时间: 2011-02-23 13:39
文章存档

2013年(2)

2012年(142)

2011年(154)

分类: Python/Ruby

2012-02-21 18:04:39

--------------------------------------------------------------------------------------
SED
单行脚本快速参考(Unix 流编辑器)                       20051229

英文标题:USEFUL ONE-LINE SCRIPTS FOR SED (Unix stream editor)
原标题:HANDY ONE-LINERS FOR SED (Unix stream editor)

整理:Eric Pement  - 电邮:pemente[at]northpark[dot]edu         版本5.5
译者:Joe Hong     - 电邮:hq00e[at]126[dot]com

在以下地址可找到本文档的最新(英文)版本:
   http://sed.sourceforge.net/sed1line.txt
   http://www.pement.org/sed/sed1line.txt

其他语言版本:
 
中文          - http://sed.sourceforge.net/sed1line_zh-CN.html
 
捷克语        - http://sed.sourceforge.net/sed1line_cz.html
 
荷语          - http://sed.sourceforge.net/sed1line_nl.html
 
法语          - http://sed.sourceforge.net/sed1line_fr.html
 
德语          - http://sed.sourceforge.net/sed1line_de.html

  葡语          - http://sed.sourceforge.net/sed1line_pt-BR.html

 

--------------------------------------------------------------------------------------
文本间隔:
--------------------------------------------------------------------------------------

1.   在每一行后面增加一空行
 sed G

2.    将原来的所有空行删除并在每一行后面增加一空行,这样在输出的文本中每一行后面将有且只有一空行。
 sed '/^$/d;G'
#d导致读入新行并且脚本回到起点

3.   在每一行后面增加两行空行
 sed 'G;G'

4.    将第一个脚本所产生的所有空行删除(即删除所有偶数行)
 sed 'n;d'
#n导致读入新行并且输出模式空间的内容,但是不回到脚本起点

5.   在匹配式样“regex”的行之前插入一空行
 sed '/regex/{x;p;x;}'

6.    在匹配式样“regex”的行之后插入一空行
 sed '/regex/G'

7.   在匹配式样“regex”的行之前和之后各插入一空行
 sed '/regex/{x;p;x;G;}'

 

-------------------------------------------------------------------------------------

编号:
-------------------------------------------------------------------------------------

1.   为文件中的每一行进行编号(简单的左对齐方式)。这里使用了“制表符”(tab,见本文末尾关于'\t'的用法的描述)而不是空格来对齐边缘。
 sed = filename | sed 'N;s/\n/\t/'

2.   对文件中的所有行编号(行号在左,文字右端对齐)。
 sed = filename | sed 'N; s/^/     /; s/ *\(.\{6,\}\)\n/\1  /'

3.   对文件中的所有行编号,但只显示非空白行的行号。
 sed '/./=' filename | sed '/./N; s/\n/ /'

4.   计算行数 (模拟 "wc -l"
 sed -n '$='

 

-----------------------------------------------------------------------------------

文本转换和替代:
-----------------------------------------------------------------------------------

1.   Unix环境:转换DOS的新行符(CR/LF)为UnixLF格式。
 sed 's/.$//'                     #
假设所有行以CR/LF结束
 sed 's/^M$//'                    #
bash/tcsh中,将按Ctrl-M改为按Ctrl-V
 
sed 's/\x0D$//'                  # ssedgsed 3.02.80,及更高版本

sed -i 's/\r$//'  filename         # 文件在windows下打开会自动在每行之后加上\r=x0d

2.   Unix环境:转换Unix的新行符(LF)为DOS格式。
 sed "s/$/`echo -e \\\r`/"        #
ksh下所使用的命令
 sed 's/$'"/`echo \\\r`/"         #
bash下所使用的命令
 sed "s/$/`echo \\\r`/"           #
zsh下所使用的命令
 sed 's/$/\r/'                    # gsed 3.02.80
及更高版本

3.    DOS环境:转换Unix新行符(LF)为DOS格式。
 sed "s/$//"                      #
方法 1
 sed -n p                         #
方法 2

4.    DOS环境:转换DOS新行符(CR/LF)为Unix格式,下面的脚本只对UnxUtils sed 4.0.7 及更高版本有效。要识别UnxUtils版本的sed可以通过其特有的“--text”选项。你可以使用帮助选项(“--help”)看其中有无一个“--text”项以此来判断所使用的是否是UnxUtils版本。其它DOS版本的的sed则无法进行这一转换。但可以用“tr”来实现这一转换。
 sed "s/\r//" infile >outfile     # UnxUtils sed v4.0.7
或更高版本
 tr -d \r outfile        # GNU tr 1.22
或更高版本

5.   去掉ascii码为032的字符

sed -i 's/\o032//g'

6.    将每一行前导的“空白字符”(空格,制表符)删除使之左对齐
 sed 's/^[ \t]*//'                #
见本文末尾关于'\t'用法的描述

7.   将每一行拖尾的“空白字符”(空格,制表符)删除
 sed 's/[ \t]*$//'                #
见本文末尾关于'\t'用法的描述

8.   将每一行中的前导和拖尾的空白字符删除
 sed 's/^[ \t]*//;s/[ \t]*$//'

9.   在每一行开头处插入5个空格(使全文向右移动5个字符的位置)
 sed 's/^/     /'

10.  79个字符为宽度,将所有文本右对齐
 sed -e :a -e 's/^.\{1,78\}$/ &/;t a'  # 78
个字符外加最后的一个空格

11.  79个字符为宽度,使所有文本居中。在方法1中,为了让文本居中每一行的前头和后头都填充了空格。 在方法2中,在居中文本的过程中只在文本的前面填充空格,并且最终这些空格将有一半会被删除。此外每一行的后头并未填充空格。
 sed  -e :a -e 's/^.\{1,77\}$/ & /;t a'                     #
方法1
 sed  -e :a -e 's/^.\{1,77\}$/ &/;t a' -e 's/\( *\)\1/\1/'  #
方法2

12.  在每一行中查找字串“foo”,并将找到的“foo”替换为“bar
 sed 's/foo/bar/'                 #
只替换每一行中的第一个“foo”字串
 sed 's/foo/bar/4'                #
只替换每一行中的第四个“foo”字串
 sed 's/foo/bar/g'                #
将每一行中的所有“foo”都换成“bar
 sed 's/\(.*\)foo\(.*foo\)/\1bar\2/' #
替换倒数第二个“foo
 sed 's/\(.*\)foo/\1bar/'            #
替换最后一个“foo

13.  只在行中出现字串“baz”的情况下将“foo”替换成“bar
 sed '/baz/s/foo/bar/g'

14.  将“foo”替换成“bar”,并且只在行中未出现字串“baz”的情况下替换
 sed '/baz/!s/foo/bar/g'

15.  不管是“scarlet”“ruby”还是“puce”,一律换成“red
 sed 's/scarlet/red/g;s/ruby/red/g;s/puce/red/g'  #
对多数的sed都有效
 gsed 's/scarlet\|ruby\|puce/red/g'               #
只对GNU sed有效

gsed -r 's/scarlet|ruby|puce/red/g'               # 只对GNU sed有效

16.  倒置所有行,第一行成为最后一行,依次类推(模拟“tac”)。由于某些原因,使用下面命令时HHsed v1.5会将文件中的空行删除
 sed '1!G;h;$!d'               #
方法1
 sed -n '1!G;h;$p'             #
方法2

17.  将行中的字符逆序排列,第一个字成为最后一字,……(模拟“rev”)
 sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'

18.  将每两行连接成一行(类似“paste”)
 sed '$!N;s/\n/ /'

19.  如果当前行以反斜杠“\”结束,则将下一行并到当前行末尾并去掉原来行尾的反斜杠和\n
 sed -e :a -e '/\\$/N; s/\\\n//; t a'

20.  如果当前行以等号开头,将当前行并到上一行末尾并以单个空格代替原来行头的“=
 sed -e :a -e '$!N;s/\n=/ /;t a' -e 'P;D'

21.  为数字字串增加逗号分隔符号,将“1234567”改为“1,234,567
 
gsed ':a;s/\B[0-9]\{3\}\>/,&/;t a'                     # GNU sed
 sed -e :a -e 's/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;t a'  # 其他sed

22.  为带有小数点和负号的数值增加逗号分隔符(GNU sed
 gsed -r ':a;s/(^|[^0-9.])([0-9]+)([0-9]{3})/\1\2,\3/g;t a'

23.  在每5行后增加一空白行 (在第5101520,等行后增加一空白行)
 gsed '0~5G'                      #
只对GNU sed有效
 sed 'n;n;n;n;G;'                 # 其他sed

24.  将文本中行B中中间,行AB前,行CB后直接的内容替换成foo,

sed ':a;N;/\nA/b;/\nC/{s/.*\nB.*\n/FOO\n/;b};b a' #不包括行A和行C

sed ':a;N;/\nA/b;/\nC/{s/.*\nB.*\nC/FOO\n/;b};b a' #不包括行A

sed ‘/A/!b;a:N; /\nC$/!{ba};/\nC$/{s/A[^A]*\nB.*\nC$/FOO\n/;} #包括行A和行C

 

---------------------------------------------------------------------------------------

选择性地显示特定列:
---------------------------------------------------------------------------------------

1.   查看ps aux的命令返回结果的COMMAND那一列

sed -r 's/(\S+ *){10}//'

 

---------------------------------------------------------------------------------------

选择性地显示特定行:
---------------------------------------------------------------------------------------

1.   显示文件中的前10行 (模拟“head”的行为)
 sed 10q

2.   显示文件中的第一行 (模拟“head -1”命令)
 sed q

3.   显示文件中的最后10行 (模拟“tail”)
 sed -e :a -e '$q;N;11,$D;b a'

4.   显示文件中的最后2行(模拟“tail -2”命令)
 sed '$!N;$!D'

5.   显示文件中的最后一行(模拟“tail -1”)
 sed '$!d'                        #
方法1
 sed -n '$p'                      #
方法2

6.   显示文件中的倒数第二行
 sed -e '$!{h;d;}' -e x              #
当文件中只有一行时,输入空行
 sed -e '1{$q;}' -e '$!{h;d;}' -e x  #
当文件中只有一行时,显示该行
 sed -e '1{$d;}' -e '$!{h;d;}' -e x  #
当文件中只有一行时,不输出

7.   只显示匹配正则表达式的行(模拟“grep”)
 sed -n '/regexp/p'               #
方法1
 sed '/regexp/!d'                 #
方法2

8.   只显示“不”匹配正则表达式的行(模拟“grep -v”)
 sed -n '/regexp/!p'              #
方法1,与前面的命令相对应
 sed '/regexp/d'                  #
方法2,类似的语法

9.   查找“regexp”并将匹配行的上一行显示出来,但并不显示匹配行
 sed -n '/regexp/{g;1!p;};h'

10.  查找“regexp”并将匹配行的下一行显示出来,但并不显示匹配行
 sed -n '/regexp/{n;p;}'

11.  显示包含“regexp”的行及其前后行,并在第一行之前加上“regexp”所在行的行号 (类似“grep -A1 -B1”)
 sed -n -e '/regexp/{=;x;1!p;g;$!N;p;D;}' -e h

12.  显示包含“AAA”、“BBB”或“CCC”的行(任意次序)
 sed '/AAA/!d; /BBB/!d; /CCC/!d'  #
字串的次序不影响结果

13.  显示包含“AAA”、“BBB”和“CCC”的行(固定次序)
 sed '/AAA.*BBB.*CCC/!d'

14.  显示包含“AAA”“BBB”或“CCC”的行 (模拟“egrep”)
 sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d    #
多数sed
 gsed '/AAA\|BBB\|CCC/!d'                        #
GNU sed有效

15.  显示包含“AAA”的段落 (段落间以空行分隔)HHsed v1.5 必须在“x;”后加入“G;”,接下来的3个脚本都是这样
 sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;'

16.  显示包含“AAA”“BBB”和“CCC”三个字串的段落 (任意次序)
 sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;/BBB/!d;/CCC/!d'

17.  显示包含“AAA”、“BBB”、“CCC”三者中任一字串的段落 (任意次序)
 sed -e '/./{H;$!d;}' -e 'x;/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d
 gsed '/./{H;$!d;};x;/AAA\|BBB\|CCC/b;d'         #
只对GNU sed有效

18.  显示包含65个或以上字符的行
 sed -n '/^.\{65\}/p'

19.  显示包含65个以下字符的行
 sed -n '/^.\{65\}/!p'            #
方法1,与上面的脚本相对应
 sed '/^.\{65\}/d'                #
方法2,更简便一点的方法

20.  显示部分文本——从包含正则表达式的行开始到最后一行结束(范围显示)
 sed -n '/regexp/,$p'

21.  显示部分文本——指定行号范围(从第8至第12行,含812行)
 sed -n '8,12p'                   #
方法1
 sed '8,12!d'                     #
方法2

22.  显示第52
 sed -n '52p'                     #
方法1
 sed '52!d'                       #
方法2
 sed '52q;d'                      #
方法3, 处理大文件时更有效率

23.  从第3行开始,每7行显示一次    
 gsed -n '3~7p'                   #
只对GNU sed有效
 sed -n '3,${p;n;n;n;n;n;n;}'     #
其他sed

24.  显示两个正则表达式之间的文本(包含)
 sed -n '/Iowa/,/Montana/p'       #
区分大小写方式

 

--------------------------------------------------------------------------------------

选择性地删除特定行:
--------------------------------------------------------------------------------------

1.   显示通篇文档,除了两个正则表达式之间的内容
 sed '/Iowa/,/Montana/d'

2.  删除文件中相邻的重复行(模拟“uniq”)只保留重复行中的第一行,其他行删除
 sed '$!N; /^\(.*\)\n\1$/!P; D'

3.   删除文件中的重复行,不管有无相邻。注意hold space所能支持的缓存大小,或者使用GNU sed
 sed -n 'G; s/\n/&&/; /^\([ -~]*\n\).*\n\1/d; s/\n//; h; P'

4.   删除除重复行外的所有行(模拟“uniq -d”)
 sed '$!N; s/^\(.*\)\n\1$/\1/; t; D'

5.   删除文件中开头的10
 sed '1,10d'

6.   删除文件中的最后一行
 sed '$d'

7.   删除文件中的最后两行
 sed 'N;$!P;$!D;$d'

8.   删除文件中的最后10
 sed -e :a -e '$d;N;2,10ba' -e 'P;D'   #
方法1
 sed -n -e :a -e '1,10!{P;N;D;};N;b a'  #
方法2

9.   删除8的倍数行
 gsed '0~8d'                           #
只对GNU sed有效
 sed 'n;n;n;n;n;n;n;d;'                #
其他sed

10.  删除匹配式样的行
 sed '/pattern/d'                      #
删除含pattern的行。当然pattern
                                       #
可以换成任何有效的正则表达式

11.  删除文件中的所有空行(与“grep '.' ”效果相同)
 sed '/^$/d'                           #
方法1
 sed '/./!d'                           #
方法2

12.  只保留多个相邻空行的第一行。并且删除文件顶部和尾部的空行。非贪婪(模拟“cat -s”)
 sed '/./,/^$/!d'        #
方法1,删除文件顶部的空行,允许尾部保留一空行
 sed '/^$/N;/\n$/D'      #
方法2,允许顶部保留一空行,尾部不留空行

13.  只保留多个相邻空行的前两行。
 sed '/^$/N;/\n$/N;//D'

14.  删除文件顶部的所有空行
 sed '/./,$!d'

15.  删除文件尾部的所有空行
 sed -e :a -e '/^\n*$/{$d;N;b a' -e '}'  #
对所有sed有效
 sed -e :a -e '/^\n*$/N;/\n$/b a'        #
同上,但只对 gsed 3.02.*有效

16.  删除每个段落的最后一行
 sed -n '/^$/{p;h;};/./{x;/./p;}'

 

------------------------------------------------------------------------------------

特殊应用:
------------------------------------------------------------------------------------

1.   移除手册页(man page)中的nroff标记。在Unix System Vbash shell下使用'echo'命令时可能需要加上 -e 选项。
 sed "s/.`echo \\\b`//g"    #
外层的双括号是必须的(Unix环境)
 sed 's/.^H//g'             #
bashtcsh, Ctrl-V 再按 Ctrl-H
 sed 's/.\x08//g'           # sed 1.5
GNU sedssed所使用的十六进制的表示方法

2.   提取新闻组或 e-mail 的邮件头
 sed '/^$/q'                #
删除第一行空行后的所有内容

3.   提取新闻组或 e-mail 的正文部分
 sed '1,/^$/d'              #
删除第一行空行之前的所有内容

4.   从邮件头提取“Subject”(标题栏字段),并移除开头的“Subject:”字样
 sed '/^Subject: */!d; s///;q'

5.   从邮件头获得回复地址
 sed '/^Reply-To:/q; /^From:/h; /./d;g;q'

6.   获取邮件地址。在上一个脚本所产生的那一行邮件头的基础上进一步的将非电邮地址的部分剃除。(见上一脚本)
 sed 's/ *(.*)//; s/>.*//; s/.*[:<] *//'

7.   在每一行开头加上一个尖括号和空格(引用信息)
 sed 's/^/> /'

8.   将每一行开头处的尖括号和空格删除(解除引用)
 sed 's/^> //'

9.   移除大部分的HTML标签(包括跨行标签)
 sed -e :a -e 's/<[^>]*>//g;/

10.  将分成多卷的uuencode文件解码。移除文件头信息,只保留uuencode编码部分。文件必须以特定顺序传给sed。下面第一种版本的脚本可以直接在命令行下输入;第二种版本则可以放入一个带执行权限的shell脚本中。(由Rahul Dhesi的一个脚本修改而来。)
 sed '/^end/,/^begin/d' file1 file2 ... fileX | uudecode   # vers. 1
 sed '/^end/,/^begin/d' "$@" | uudecode                    # vers. 2

11.  将文件中的段落以字母顺序排序。段落间以(一行或多行)空行分隔。GNU sed使用字元“\v”来表示垂直制表符,这里用它来作为换行符的占位符——当然你也可以用其他未在文件中使用的字符来代替它。
 sed '/./{H;d;};x;s/\n/={NL}=/g' file | sort | sed '1s/={NL}=//;s/={NL}=/\n/g'
 gsed '/./{H;d};x;y/\n/\v/' file | sort | sed '1s/\v//;y/\v/\n/'

12.  分别压缩每个.TXT文件,压缩后删除原来的文件并将压缩后的.ZIP文件命名为与原来相同的名字(只是扩展名不同)。(DOS环境:“dir /b”显示不带路径的文件名)。
 echo @echo off >zipup.bat
 dir /b *.txt | sed "s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/" >>zipup.bat


如果你有其他的单行脚本想与大家分享或者你发现了本文档中错误的地方,请发电
子邮件给本文档的作者(Eric Pement)。邮件中请记得提供你所使用的sed版本、 
sed所运行的操作系统及对问题的适当描述。本文所指的单行脚本指命令行的长
度在65个字符或65个以下的sed脚本〔译注1〕。本文档的各种脚本是由以下所列作
者所写或提供:

 Al Aab                               # 建立了“seders”邮件列表
 Edgar Allen                          #
许多方面
 Yiorgos Adamopoulos                  #
许多方面
 Dale Dougherty                       #
sed & awk》作者
 Carlos Duarte                        #
do it with sed》作者
 Eric Pement                          #
本文档的作者
 Ken Pizzini                          # GNU sed v3.02
的作者
 S.G. Ravenhall                       #
html标签脚本
 Greg Ubben                           #
有诸多贡献并提供了许多帮助
-------------------------------------------------------------------------

译注1:大部分情况下,sed脚本无论多长都能写成单行的形式(通过`-e'选项和`;'
号)——只要命令解释器支持,所以这里说的单行脚本除了能写成一行还对长度有
所限制。因为这些单行脚本的意义不在于它们是以单行的形式出现。而是让用户能
方便地在命令行中使用这些紧凑的脚本才是其意义所在。

 

阅读(631) | 评论(0) | 转发(2) |
给主人留下些什么吧!~~