Chinaunix首页 | 论坛 | 博客
  • 博客访问: 1375013
  • 博文数量: 317
  • 博客积分: 1557
  • 博客等级: 上尉
  • 技术积分: 1208
  • 用 户 组: 普通用户
  • 注册时间: 2008-02-26 23:38
个人简介

如果想出发,就不要等到明天!

文章分类

全部博文(317)

文章存档

2016年(1)

2015年(41)

2014年(152)

2013年(114)

2012年(4)

2011年(1)

2009年(4)

分类: LINUX

2015-04-07 12:56:11

接着上一篇继续讲

发生异常会跳到异常向量表执行,但异常向量表里放的是一条跳转指令,调到哪里呢?
当然是中断异常处理函数,这部分源码很长,从999行一直到1127行,我们取其中一段分析(irq异常情况)

__stubs_start:
/*
 * Interrupt dispatcher
 */
vector_stub irq, IRQ_MODE, 4

.long __irq_usr @  0  (USR_26 / USR_32)
.long __irq_invalid @  1  (FIQ_26 / FIQ_32)
.long __irq_invalid @  2  (IRQ_26 / IRQ_32)
.long __irq_svc @  3  (SVC_26 / SVC_32)
.long __irq_invalid @  4
.long __irq_invalid @  5
.long __irq_invalid @  6
.long __irq_invalid @  7
.long __irq_invalid @  8
.long __irq_invalid @  9
.long __irq_invalid @  a
.long __irq_invalid @  b
.long __irq_invalid @  c
.long __irq_invalid @  d
.long __irq_invalid @  e
.long __irq_invalid @  f
……此处省略n行
.LCvswi:
.word vector_swi

.globl __stubs_end
__stubs_end:

是不是想说什么玩意,刚开始我也想说,但别急,来分析一下上面的代码:
vector_stub irq, IRQ_MODE, 4 是个宏,定义在959行:

.macro vector_stub, name, mode, correction=0
.align 5

vector_\name:
.if \correction
sub lr, lr, #\correction
.endif

@
@ Save r0, lr_ (parent PC) and spsr_
@ (parent CPSR)
@
stmia sp, {r0, lr} @ save r0, lr
mrs lr, spsr
str lr, [sp, #8] @ save spsr

@
@ Prepare for SVC32 mode.  IRQs remain disabled.
@
mrs r0, cpsr
eor r0, r0, #(\mode ^ SVC_MODE | PSR_ISETSTATE)
msr spsr_cxsf, r0

@
@ the branch table must immediately follow this code
@
and lr, lr, #0x0f
 THUMB( adr r0, 1f )
 THUMB( ldr lr, [r0, lr, lsl #2] )
mov r0, sp
 ARM( ldr lr, [pc, lr, lsl #2] )
movs pc, lr @ branch to handler in SVC mode
ENDPROC(vector_\name)

.align 2
@ handler addresses follow this label
1:
.endm

将上面的展开之后,就出现了标号vector_irq,然后做保存现场、切换工作模式等工作

接下来的代码就是.long __irq_usr @  0  (USR_26 / USR_32) 等,这段当中有用的只有
.long __irq_usr @  0  (USR_26 / USR_32)  // 在用户模式下发生中断异常
.long __irq_svc @  3  (SVC_26 / SVC_32)  // 在管理模式下发生中断异常

这些拷贝完成之后,就可以正常的异常处理工作了

假如在用户模式下发生了一个外部中断(irq异常模式),CPU会跳转到异常向量表取出
W(b) vector_irq + stubs_offset            // 0x18
执行,它是一条跳转指令,会跳到上面解析出的标号vector_irq地方,然后执行,接着跳转到__irq_usr
__irq_usr:
usr_entry
kuser_cmpxchg_check
irq_handler
get_thread_info tsk
mov why, #0
b ret_to_user_from_irq
 UNWIND(.fnend )
ENDPROC(__irq_usr)

这里有个irq_handler,它也是一个宏,看下它的定义

.macro irq_handler
#ifdef CONFIG_MULTI_IRQ_HANDLER
ldr r1, =handle_arch_irq
mov r0, sp
adr lr, BSYM(9997f)
ldr pc, [r1]
#else
arch_irq_handler_default
#endif

由于没有定义:CONFIG_MULTI_IRQ_HANDLER,所以简化下就是执行:arch_irq_handler_default
这有时一个宏,根据包含的头文件看出查找是定义在\linux-3.3\arch\arm\include\asm\entry-macro-multi.S中

.macro arch_irq_handler_default
get_irqnr_preamble r6, lr
1: get_irqnr_and_base r0, r2, r6, lr  /* 这是一个宏,定义在\linux-3.3\arch\arm\include\asm\hardware\entry-macro-iomd.S
                                        它会获取终端号存在r0里面*/ 
movne r1, sp
@
@ routine called with r0 = irq number, r1 = struct pt_regs *
@
adrne lr, BSYM(1b)
bne asm_do_IRQ

#ifdef CONFIG_SMP
/*
* XXX
*
* this macro assumes that irqstat (r2) and base (r6) are
* preserved from get_irqnr_and_base above
*/
ALT_SMP(test_for_ipi r0, r2, r6, lr)
ALT_UP_B(9997f)
movne r1, sp
adrne lr, BSYM(1b)
bne do_IPI
#endif
9997:
.endm

看到上面的asm_do_IRQ你是不是笑了,终于看到曙光了。它是中断的总入口函数,并传入了中断号,
下面的内核代码就不分析了,参见中断处理相关内容。


现在有一个疑问:刚才我们执行异常向量表的跳转指令:W(b) vector_irq + stubs_offset       // 0x18
为什么跳转的地址是上面的这个,加上stubs_offset是什么意思,它又代表什么?

先找出stubs_offset的宏定义:
.equ stubs_offset, __vectors_start + 0x200 - __stubs_start

异常向量表使用了两种类型的跳转指令:
    W(b) vector_und + stubs_offset
    W(ldr) pc, .LCvswi + stubs_offset
    
对于B跳转指令的执行,是相对当前的PC值加上偏移地址,在重定位后,由于跳转指令所在位置
与将要跳转到的目的位置之间的相对位置偏移量发生了变化,故要加一个偏移量。例如:以前这
两个位置的相对偏移量是10,重定位后变成了15,那么在进行相对跳转的时候就要再加上偏移量5

对于ldr指令,它是绝对地址跳转,就是直接把要跳转的地址赋给PC,但是重定位后,要跳转的这个
绝对地址处的代码也发生了偏移,偏移量的值和上一种情况是一样的,因为LCvswi是随
__stubs_start一起进行重定位的(.LCvswi在__stubs_start~~__stubs_end段中定义)。
.LCvswi:
    .word vector_swi
    
所以这两种情况都要加上一个偏移量stubs_offset,那么这个值是怎么计算出来的呢?
下面是网上一位仁兄的计算方法:

首先我们要知道,上面重定位的两部分代码,在重定位前后,其每部分内部的相对位置是没有发生变化的,
只是两部分之间的部分偏移发生了变化。

(irq_entry - _vectors_start) = (irq_entry’ - _vectors_start’) = V1       中断向量表
(vector_irq - _stubs_start) =  (vector_irq’ - _stubs_start’) = V2          目的代码


重定位前:
irq_entry = _vectors_start + V1           IRQ向量表地址    
vector_irq =  _stubs_start + V2          IRQ跳转目的地址  
跳转地址与目的地址间的偏移(相对地址):
P1 = (vector_irq - irq_entry) =(_stubs_start - _vectors_start) + ( V2 - V1)


重定位后:
irq_entry’ = _vectors_start’ + V1         IRQ向量表地址     
vector_irq’ =  _stubs_start’ + V2               IRQ跳转目的地址   
跳转地址与目的地址间的偏移(重定位后相对地址):
P2 = (vector_irq’ - irq_entry’) =(_stubs_start’ - _vectors_start’) + ( V2 - V1)


由此可得出重定位后的相对地址和重定位前的相对地址变化量:
P = P2 – P1
= ((_stubs_start’ - _vectors_start’) + ( V2 - V1)) – ((_stubs_start - _vectors_start) + ( V2 - V1))
= 0x200 - (_stubs_start - _vectors_start)
= __vectors_start + 0x200 - __stubs_start


这节讲的是针对irq异常,根据之前的博文我们知道系统调用是产生swi异常的,下一篇博文就以系统调用来分析一下swi异常

阅读(902) | 评论(0) | 转发(0) |
给主人留下些什么吧!~~
评论热议
请登录后评论。

登录 注册