Chinaunix首页 | 论坛 | 博客
  • 博客访问: 1379976
  • 博文数量: 317
  • 博客积分: 1557
  • 博客等级: 上尉
  • 技术积分: 1208
  • 用 户 组: 普通用户
  • 注册时间: 2008-02-26 23:38
个人简介

如果想出发,就不要等到明天!

文章分类

全部博文(317)

文章存档

2016年(1)

2015年(41)

2014年(152)

2013年(114)

2012年(4)

2011年(1)

2009年(4)

分类: 嵌入式

2013-04-26 10:14:23

1.1       U-Boot工作过程

U-Boot启动内核的过程可以分为两个阶段,两个阶段的功能如下:

       1)第一阶段的功能

?  硬件设备初始化

?  加载U-Boot第二阶段代码到RAM空间

?  设置好栈

?  跳转到第二阶段代码入口

       2)第二阶段的功能

?  初始化本阶段使用的硬件设备

?  检测系统内存映射

?  将内核从Flash读取到RAM

?  为内核设置启动参数

?  调用内核

1.1.1             U-Boot启动第一阶段代码分析

       第一阶段对应的文件是cpu/arm920t/start.Sboard/samsung/mini2440/lowlevel_init.S

       U-Boot启动第一阶段流程如下:

2.1 U-Boot启动第一阶段流程

       根据cpu/arm920t/u-boot.lds中指定的连接方式:

ENTRY(_start)

SECTIONS

{

       . = 0x00000000;

       . = ALIGN(4);

       .text :

       {

                     cpu/arm920t/start.o    (.text)

                board/samsung/mini2440/lowlevel_init.o (.text)

                 board/samsung/mini2440/nand_read.o (.text)

              *(.text)

       }

       … …

}

       第一个链接的是cpu/arm920t/start.o,因此u-boot.bin的入口代码在cpu/arm920t/start.o中,其源代码在cpu/arm920t/start.S中。下面我们来分析cpu/arm920t/start.S的执行。

1.      硬件设备初始化

1)设置异常向量

       cpu/arm920t/start.S开头有如下的代码:

.globl _start

_start:    b     start_code                         /* 复位 */

       ldr   pc, _undefined_instruction      /* 未定义指令向量 */

       ldr   pc, _software_interrupt            /*  软件中断向量 */

       ldr   pc, _prefetch_abort                  /*  预取指令异常向量 */

       ldr   pc, _data_abort                        /*  数据操作异常向量 */

       ldr   pc, _not_used                           /*  未使用   */

       ldr   pc, _irq                                     /*  irq中断向量  */

       ldr   pc, _fiq                                     /*  fiq中断向量  */

/*  中断向量表入口地址 */

_undefined_instruction:    .word undefined_instruction

_software_interrupt:  .word software_interrupt

_prefetch_abort:  .word prefetch_abort

_data_abort:        .word data_abort

_not_used:          .word not_used

_irq:                     .word irq

_fiq:                     .word fiq

       .balignl 16,0xdeadbeef

       以上代码设置了ARM异常向量表,各个异常向量介绍如下:

2.1 ARM异常向量表

地址 

异常 

进入模式

描述

0x00000000 

复位

管理模式

复位电平有效时,产生复位异常,程序跳转到复位处理程序处执行

0x00000004 

未定义指令

未定义模式

遇到不能处理的指令时,产生未定义指令异常

0x00000008

软件中断

管理模式

执行SWI指令产生,用于用户模式下的程序调用特权操作指令

0x0000000c

预存指令

中止模式

处理器预取指令的地址不存在,或该地址不允许当前指令访问,产生指令预取中止异常

0x00000010

数据操作

中止模式

处理器数据访问指令的地址不存在,或该地址不允许当前指令访问时,产生数据中止异常

0x00000014

未使用

未使用

未使用

0x00000018

IRQ

IRQ

外部中断请求有效,且CPSR中的I位为0时,产生IRQ异常

0x0000001c

FIQ

FIQ

快速中断请求引脚有效,且CPSR中的F位为0时,产生FIQ异常

       cpu/arm920t/start.S中还有这些异常对应的异常处理程序。当一个异常产生时,CPU根据异常号在异常向量表中找到对应的异常向量,然后执行异常向量处的跳转指令,CPU就跳转到对应的异常处理程序执行。

       其中复位异常向量的指令“b start_code”决定了U-Boot启动后将自动跳转到标号“start_code”处执行。

2CPU进入SVC模式

start_code:

       /*

        * set the cpu to SVC32 mode

        */

       mrs r0, cpsr

       bic  r0, r0, #0x1f        /*工作模式位清零 */

       orr   r0, r0, #0xd3              /*工作模式位设置为“10011”(管理模式),并将中断禁止位和快中断禁止位置1 */

       msr cpsr, r0

       以上代码将CPU的工作模式位设置为管理模式,并将中断禁止位和快中断禁止位置一,从而屏蔽了IRQFIQ中断。

3)设置控制寄存器地址

# if defined(CONFIG_S3C2400)

#  define pWTCON 0x15300000

#  define INTMSK  0x14400008

#  define CLKDIVN      0x14800014

#else      /* s3c2410s3c2440下面4个寄存器地址相同 */

#  define pWTCON 0x53000000               /* WATCHDOG控制寄存器地址 */

#  define INTMSK  0x4A000008                     /* INTMSK寄存器地址  */

#  define INTSUBMSK 0x4A00001C      /* INTSUBMSK寄存器地址 */

#  define CLKDIVN      0x4C000014                   /* CLKDIVN寄存器地址 */

# endif

       对与s3c2440开发板,以上代码完成了WATCHDOGINTMSKINTSUBMSKCLKDIVN四个寄存器的地址的设置。各个寄存器地址参见参考文献[4]

4)关闭看门狗

       ldr   r0, =pWTCON

       mov       r1, #0x0

       str   r1, [r0]   /* 看门狗控制器的最低位为0时,看门狗不输出复位信号 */

       以上代码向看门狗控制寄存器写入0,关闭看门狗。否则在U-Boot启动过程中,CPU将不断重启。

5)屏蔽中断

       /*

        * mask all IRQs by setting all bits in the INTMR - default

        */

       mov       r1, #0xffffffff     /* 某位被置1则对应的中断被屏蔽 */

       ldr   r0, =INTMSK

       str   r1, [r0]

       INTMSK主中断屏蔽寄存器,每一位对应SRCPND中断源引脚寄存器)中的一位,表明SRCPND相应位代表的中断请求是否被CPU所处理

         根据参考文献4INTMSK寄存器是一个32位的寄存器,每位对应一个中断,向其中写入0xffffffff就将INTMSK寄存器全部位置一,从而屏蔽对应的中断。

# if defined(CONFIG_S3C2440)

          ldr  r1, =0x7fff      

          ldr  r0, =INTSUBMSK

          str  r1, [r0]

# endif

       INTSUBMSK每一位对应SUBSRCPND中的一位,表明SUBSRCPND相应位代表的中断请求是否被CPU所处理

       根据参考文献4INTSUBMSK寄存器是一个32位的寄存器,但是只使用了低15位。向其中写入0x7fff就是将INTSUBMSK寄存器全部有效位(低15位)置一,从而屏蔽对应的中断。

6)设置MPLLCON,UPLLCON, CLKDIVN

# if defined(CONFIG_S3C2440) 

#define MPLLCON   0x4C000004

#define UPLLCON   0x4C000008  

          ldr  r0, =CLKDIVN  

          mov  r1, #5

          str  r1, [r0]

 

          ldr  r0, =MPLLCON

          ldr  r1, =0x7F021 

          str  r1, [r0]

 

    ldr  r0, =UPLLCON 

          ldr  r1, =0x38022

          str  r1, [r0]

# else

       /* FCLK:HCLK:PCLK = 1:2:4 */

       /* default FCLK is 120 MHz ! */

       ldr   r0, =CLKDIVN

       mov       r1, #3

       str   r1, [r0]

#endif

       CPU上电几毫秒后,晶振输出稳定,FCLK=Fin(晶振频率),CPU开始执行指令。但实际上,FCLK可以高于Fin,为了提高系统时钟,需要用软件来启用PLL。这就需要设置CLKDIVNMPLLCONUPLLCON3个寄存器。

       CLKDIVN寄存器用于设置FCLKHCLKPCLK三者间的比例,可以根据表2.2来设置。

2.2 S3C2440 CLKDIVN寄存器格式

CLKDIVN

说明

初始值

HDIVN

[2:1]

00 : HCLK = FCLK/1.

01 : HCLK = FCLK/2.

10 : HCLK = FCLK/4 (当 CAMDIVN[9] = 0 时)

HCLK= FCLK/8  (当 CAMDIVN[9] = 1 时)

11 : HCLK = FCLK/3 (当 CAMDIVN[8] = 0 时)

HCLK = FCLK/6 (当 CAMDIVN[8] = 1时)

00

PDIVN

[0]

0: PCLK = HCLK/1   1: PCLK = HCLK/2

0

       设置CLKDIVN5,就将HDIVN设置为二进制的10,由于CAMDIVN[9]没有被改变过,取默认值0,因此HCLK = FCLK/4PDIVN被设置为1,因此PCLK= HCLK/2。因此分频比FCLK:HCLK:PCLK = 1:4:8

       MPLLCON寄存器用于设置FCLKFin的倍数。MPLLCON的位[19:12]称为MDIV,位[9:4]称为PDIV,位[1:0]称为SDIV

       对于S3C2440FCLKFin的关系如下面公式:

       MPLL(FCLK) = (2×m×Fin)/(p×)

       其中: m=MDIC+8p=PDIV+2s=SDIV

       MPLLCONUPLLCON的值可以根据参考文献4“PLL VALUE SELECTION TABLE”设置。该表部分摘录如下:

2.3 推荐PLL

输入频率

输出频率

MDIV

PDIV

SDIV

12.0000MHz

48.00 MHz

56(0x38)

2

2

12.0000MHz

405.00 MHz

127(0x7f)

2

1

       mini2440系统主频设置为405MHZUSB时钟频率设置为48MHZ时,系统可以稳定运行,因此设置MPLLCONUPLLCON为:

       MPLLCON=(0x7f<<12) | (0x02<<4) | (0x01) = 0x7f021

       UPLLCON=(0x38<<12) | (0x02<<4) | (0x02) = 0x38022

7)关闭MMUcache

       接着往下看:

#ifndef CONFIG_SKIP_LOWLEVEL_INIT

       bl    cpu_init_crit

#endif

       cpu_init_crit这段代码在U-Boot正常启动时才需要执行,若将U-BootRAM中启动则应该注释掉这段代码。

       下面分析一下cpu_init_crit到底做了什么:

320  #ifndef CONFIG_SKIP_LOWLEVEL_INIT

321  cpu_init_crit:

322      /*

323       * 使数据cache与指令cache无效 */

324       */ 

325      mov       r0, #0

326      mcr p15, 0, r0, c7, c7, 0    /* c7写入0将使ICacheDCache无效*/

327      mcr p15, 0, r0, c8, c7, 0    /* c8写入0将使TLB失效 */

328 

329      /*

330       * disable MMU stuff and caches

331       */

332      mrc p15, 0, r0, c1, c0, 0    /*  读出控制寄存器到r0  */

333      bic  r0, r0, #0x00002300   @ clear bits 13, 9:8 (--V- --RS)

334      bic  r0, r0, #0x00000087   @ clear bits 7, 2:0 (B--- -CAM)

335      orr   r0, r0, #0x00000002   @ set bit 2 (A) Align

336      orr   r0, r0, #0x00001000   @ set bit 12 (I) I-Cache

337      mcr p15, 0, r0, c1, c0, 0    /*  保存r0到控制寄存器  */

338 

339      /*

340       * before relocating, we have to setup RAM timing

341       * because memory timing is board-dependend, you will

342       * find a lowlevel_init.S in your board directory.

343       */

344      mov       ip, lr

345 

346      bl    lowlevel_init

347 

348      mov       lr, ip

349      mov       pc, lr

350  #endif /* CONFIG_SKIP_LOWLEVEL_INIT */

       代码中的c0c1c7c8都是ARM920T的协处理器CP15的寄存器。其中c7cache控制寄存器,c8TLB控制寄存器。325~327行代码将0写入c7c8,使CacheTLB内容无效。

       332~337行代码关闭了MMU。这是通过修改CP15c1寄存器来实现的,先看CP15c1寄存器的格式(仅列出代码中用到的位):

2.3 CP15c1寄存器格式(部分)

15

14

13

12

11

10

管理员在2009年8月13日编辑了该文章文章。 -->

阅读(242) | 评论(0) | 转发(0) |
给主人留下些什么吧!~~
评论热议
请登录后评论。

登录 注册